REBOL [
    Author: "Viktor Pavlu"
    Title:  "ORF Programm"
    Date:   20-jan-2002
    Desc:   "displays the tv programme for orf1 & orf2"
]

sender: "orf1"
datum: now/date

either error? try [ view? ][
    sender: trim to-string ask "sender(orf1/orf2)? "
    datum:  trim to-string ask rejoin [ "datum(" now/date ")? " ]
] [
    sender: trim to-string request-text/title/default "Sender?" "orf1"
    datum:  trim to-string request-date
]

if not-equal? sender "orf2" [ sender: "orf1" ]
if equal? datum "" [ datum: to-string now/date ]

set [ d m y ] parse to-string datum "-"
m: to-string index? find [ "Jan" "Feb" "Mar" "Apr" "May" "Jun" "Jul" "Aug" "Sep" "Oct" "Nov" "Dec" ] m
if equal? length? d 1 [ d: join "0" d ]
if equal? length? m 1 [ m: join "0" m ]

url: to-url rejoin [ "http://tv.orf.at/program/" sender "/" y m d "/" ]

file: read url
programm: copy []

parse file [
    some [
        thru {<font color=#} thru { size=+1>} copy zeit to {</font>} ( append programm zeit ) thru {</font>}
        thru {<font size="-1"><b>} copy name to {</b>} (append programm name ) thru {</b>}
    ]
]

forskip programm 2 [
    print rejoin [ first programm tab second programm ]
]

halt